月イチM5工作——M5 Din Meterと計量ユニットで販売管理タグを作る

void _open_app()
    {
        int matching_index = getSelectedOptionIndex();
        if (matching_index == 0)
            _ft->_disp_test();
        else if (matching_index == 1)
            _ft->_disp_set_brightness();
        else if (matching_index == 2)
            _ft->_rtc_test();
        else if (matching_index == 3)
            _ft->_wifi_test();
        else if (matching_index == 4)
            _ft->_encoder_test_user();
        // else if (matching_index == 5)
        //     printf("todo\n");
        else if (matching_index == 5)
        //    _ft->_arkanoid_start(); // ブロック崩しを呼び出さない
              _ft->_io_test(); // ブロック崩しの代わりに io_test を呼び出す
        else if (matching_index == 6)
            _ft->_rtc_wakeup_test_user();
        else if (matching_index == 7)
            _ft->_power_off();
    }
};

view.cppより一部抜粋。

#include "M5GFX.h" #include "M5Unified.h" #include "M5DinMeter.h"

M5GFX display;
M5Canvas canvasA(&display);

void setup() {
  auto cfg = M5.config();     
  DinMeter.begin(cfg, true);  // DinMeterの機能を使うために必要
  display.begin();            
  display.setRotation(1);     
  display.fillScreen(TFT_BLACK);
  canvasA.createSprite(display.width(), display.height());
}

int dispMode = 0;  // モード切り替え用のフラグ
long oldPrice = 2530;
float price = 2530;

void loop() {
  DinMeter.update();  // DinMeterの機能を使うために必要

  // 販売価格を変更する
  if (dispMode == 1) {
    long newPrice = DinMeter.Encoder.read();
    if (newPrice != oldPrice) {
      DinMeter.Speaker.tone(8000, 20);
      oldPrice = newPrice;
      price = newPrice;
    }
  }

  // 販売価格を表示するスプライトを作る
  canvasA.fillRect(0, 0, display.width(), display.height(), BLACK);
  canvasA.setTextColor(WHITE);
  canvasA.setTextSize(0.6);
  canvasA.setFont(&fonts::lgfxJapanGothicP_40);
  canvasA.setCursor(0, 40);
  canvasA.println("書籍「京島の十月」");
  canvasA.printf("Price: %.0fyen", price);
  if (dispMode == 1) {
    canvasA.printf(" ←");
  }

  // ボタンを押すとモードが変わる
  if (DinMeter.BtnA.wasPressed()) {
    dispMode = (dispMode + 1) % 2;
    DinMeter.Encoder.write(price); // 現在の価格をエンコーダーの値にする
  }
  
  canvasA.pushSprite(&display, 20, 0);
  delay(10);
}

fabcross_dinMeter01.ino

#include "M5DinMeter.h"
#include "M5GFX.h"
#include "M5Unified.h"
#include "UNIT_SCALES.h"  // 計量ユニットを使うために必要

M5GFX display;
M5Canvas canvasB(&display);
UNIT_SCALES scales;  // 計量ユニットを定義

void setup() {
  auto cfg = M5.config();
  DinMeter.begin(cfg, true);  // DinMeterの機能を使うために必要
  display.begin();
  display.setRotation(1);
  display.fillScreen(TFT_BLACK);
  canvasB.createSprite(display.width(), display.height());

// 計量ユニットとの接続を確認し、成功したらLEDを光らせる
  while (!scales.begin(&Wire, 2, 1, DEVICE_DEFAULT_ADDR)) {  
    DinMeter.Display.print("scales connect error");
    delay(1000);
  }
  scales.setLEDColor(0x001000);
}

float unit = 150; // 商品一個あたりの重さ
int dispMode = 0;  // モード切り替え用のフラグ
long oldPosition = -999;

void loop() {
  DinMeter.update();

  // 商品一個あたりの重さを調整する
  if (dispMode == 1) {
    long newPosition = DinMeter.Encoder.read();
    if (newPosition != oldPosition) {
      DinMeter.Speaker.tone(8000, 20);
      oldPosition = newPosition;
      unit = newPosition;
      if (unit < 1) unit = 1;
    }
  }

  // 重さと個数を表示するスプライトを作る
  float weight = scales.getWeight(); // 現在の重さを計測する
  if (isnan(weight)) {
    weight = 1.0;  // weightがNaNだった場合、1.0を代入
  }
  canvasB.fillRect(0, 0, display.width(), 120, BLACK);
  canvasB.setTextColor(WHITE);
  canvasB.setTextSize(0.6);
  canvasB.setFont(&fonts::lgfxJapanGothic_40);
  canvasB.setCursor(0, 0);
  canvasB.printf("Weight: %.0fg\n", weight); //重さを表示
  canvasB.printf("Stock: %dpcs\n", int(weight / unit)); // 個数を表示
  canvasB.printf("Unit: %.0fg/pcs", unit); //商品一個あたりの重さを表示
  if (dispMode == 1) {
    canvasB.printf(" ←");
  }

  // ボタンを押すとモードが変わる
  if (DinMeter.BtnA.wasPressed()) {
    dispMode = (dispMode + 1) % 2;
    DinMeter.Encoder.write(unit);
  }

  canvasB.pushSprite(&display, 20, 0);
  delay(10);
}

fabcross_dinMeter02.ino